[CS:GO] - [Plugin] "AbNeR ResetScore simplificat"

[NiGHT]

• Descriere: Reseteaza scorul si salveaza scorul cand un jucator foloseste retry pe acea mapa.
• Descărcare: 

  #include <sourcemod>
  #include <cstrike>
  #include <sdktools_gamerules>
  
  #pragma newdecls required
  #pragma semicolon 1
  
  #define PVERSION "1.2"
  
  StringMap PlayerList;
  public Plugin myinfo =
  {
  	name = "[CSS/CS:GO] AbNeR ResetScore, simplified by .NiGHT",
  	author = "AbNeR_CSS",
  	description = "Type !resetscore to reset your score",
  	version = PVERSION,
  	url = "www.tecnohardclan.com"
  };
  
  public void OnPluginStart()
  {  
  	RegConsoleCmd("sm_resetscore", CommandResetScore);
  	RegConsoleCmd("sm_rs", CommandResetScore);
  
  	PlayerList = new StringMap();
  }
  
  public void OnMapStart()
  {
  	PlayerList.Clear();
  }
  
  public void OnClientDisconnect(int client)
  {
  	if(!IsClientInGame(client) || IsFakeClient(client) || !client || GameRules_GetProp("m_bWarmupPeriod") == 1)
  		return;
  	
  	char steamid[32];
  	GetClientAuthId(client, AuthId_Steam2, steamid, sizeof(steamid));
  
  	int score[5];
  	score[0] = GetClientFrags(client);
  	score[1] = CS_GetClientAssists(client);
  	score[2] = GetClientDeaths(client);
  	score[3] = CS_GetMVPCount(client);
  	score[4] = CS_GetClientContributionScore(client);
  
  	PlayerList.SetArray(steamid, score, 5);
  }
  
  public void OnClientPostAdminCheck(int client)
  {
  	if(IsFakeClient(client))
  		return;
  	
  	char steamid[32];
  	GetClientAuthId(client, AuthId_Steam2, steamid, sizeof(steamid));
  	int score[5];
  	if(PlayerList.GetArray(steamid, score, 5))
  	{
  		SetEntProp(client, Prop_Data, "m_iFrags", score[0]);
  		CS_SetClientAssists(client, score[1]);
  		SetEntProp(client, Prop_Data, "m_iDeaths", score[2]);
  		CS_SetMVPCount(client, score[3]);
  		CS_SetClientContributionScore(client, score[4]);
  	}
  }
  
  public Action CommandResetScore(int client, int args)
  {
  	if(!IsClientInGame(client))
  	{
  		return Plugin_Handled;
  	}
  	if(GetClientDeaths(client) == 0 && GetClientFrags(client) == 0 && CS_GetMVPCount(client) == 0)
  	{
  		if(CS_GetClientAssists(client) == 0)
  		{
  			PrintToChat(client, "[\x02USP\x01] \x01Your score is already\x04 0");
  			return Plugin_Handled;
  		}
  	}
  	
  	SetEntProp(client, Prop_Data, "m_iFrags", 0);
  	SetEntProp(client, Prop_Data, "m_iDeaths", 0);
  	CS_SetMVPCount(client, 0);
  	CS_SetClientAssists(client, 0);
  	CS_SetClientContributionScore(client, 0);
  	
  	switch(GetClientTeam(client))
  	{
  		case 2: PrintToChatAll("[\x02USP\x01] Player \x02%N \x01has just reset his score !", client);
  		case 3: PrintToChatAll("[\x02USP\x01] Player \x0B%N \x01has just reset his score !", client);
  		default: PrintToChatAll("[\x02USP\x01] Player \x04%N \x01has just reset his score !", client);
  	}
  	return Plugin_Handled;
  }

   

• Denumire plugin: AbNeR ResetScore
• Link oficial: https://forums.alliedmods.net/showthread.php?p=1871412
• Imagini (opţional): - 
• Alte precizari/detalii: Versiunea de mai sus nu mai are cvar uri si comenzile de admin + e putin modificata.